Load a saved equation using a script

Hi xtrasico,

That is an interesting question.  I have never tried something like that before but it does make sense.  Here is the script that I cam up for it (I have also attached it).  As you can see I first check to make sure it is an IDEA equation file and then I read the equation.  I also found that the equation is stored with \L to indicate the list separator as it will be different depending on the language version of IDEA, so I needed to write a loop that looks for and replaces the \L.  Let me know how it works for you.

Sub Main
	Call DirectExtraction()	'Sample-Bank Transactions.imd
End Sub

' Data: Direct Extraction
Function DirectExtraction
	Dim sEquation As String
	Set db = Client.OpenDatabase("Sample-Bank Transactions.imd")
	Set task = db.Extraction
	task.IncludeAllFields
	dbName = "Cheque.IMD"
	'get the equation - 
	sEquation = getExtractionEquation("Cheque.EQX")
	task.AddExtraction dbName, "", sEquation
	task.PerformTask 1, db.Count
	Set task = Nothing
	Set db = Nothing
	Client.OpenDatabase (dbName)
End Function

'Import an equation that has been saves as a *.eqx file to be used in an IDEAScript
Function getExtractionEquation(sEquationName As String) As String
	Const ForReading = 1
	
	Dim fso As Object
	Dim ts As Object
	Dim task As Object
	Dim sPath As String
	Dim sText As String
	Dim iLine As Integer
	Dim iLengh As Integer
	Dim i As Integer
	Dim sChars As String
	Dim sEquation As String
	
	'assumes that equation is stored in project working directory under the Equation.ILB.  Equation should be called with full name and extension but no path.
	sPath = Client.WorkingDirectory & "Equations.ILB\" & sEquationName
	
	'Use the FileSystemObject to read the equation file
	Set fso = CreateObject("Scripting.FileSystemObject")
	Set ts = fso.OpenTextFile(sPath, ForReading)
	
	iLine = 1
	'Loop through the equation file.
	Do Until ts.AtEndOfStream
		sText = ts.ReadLine
		'check to make sure the first line has IDEA32 on it (note this could change for future versions of IDEA)
		If iLine = 1 And Left(sText,6) <> "IDEA32" Then
			MsgBox "This does not appear to be a valid equation file"
			getExtractionEquation = ""
			Exit Function
		End If
		iLine = iLine + 1
	Loop
	Set ts = Nothing
	Set fso = Nothing
	
	'update the equation with the separator values
	Set task = CreateObject("idea.ConfigureIdea")
	sListSeparator = task.ListSeparator

	'swap the "\L" character for the list separator, this could be the "," or the ";" depending on language version of IDEA.
	iLengh = Len(sText)
	For i = 1 To iLengh
		sChars = Mid(sText, i , 2)
		If sChars = "\L" Then
			sEquation = sEquation & sListSeparator
			i = i + 1 'skip a character as we have replace two characters for one
		Else
			sEquation = sEquation & Left(sChars, 1) 'only take the first character in the sChars variable
		End If
	Next i

	getExtractionEquation = sEquation
	Set task = Nothing
	
End Function

Hi there, more than likely you are using the Unicode or a different language version of IDEA and the "Equation.ILB" is different.  I think in the Unicode version is is "Equation.ILBx" but I am not 100% on that.  You will have to use file explorer to go into that project (or any IDEA project) and see what the directory is.

I am not sure why it is not working.  Did you try adding msgbox sPath and comparing it with the file explorer?  If the path is correct and file is there I am not sure why it is not working.

I have a few things I need to check into to fix this problem.  I knew about the sub-folder problem, I think there is a function to get around this but I can't seem to find it.  Also I always thought the period was surrounding the .AND. in all languages so this I need to check out if it is different depending on the language.